Amiga Plus 1999 #2/Amiga Plus CD - 1999 - No. 2.iso/System-Boost/Workbench/Archive/ViewDiz/ViewDiz-extras/S/PlayTune.rexx

OS/2 REXX Batch file | 1998-11-09 | 2.9 KB | 178 lines

/*
 $VER: PlayTune.Rexx 1.2 (23.9.98) Mikael Lund
*/

_PAUSE="Playing paused/resumed."
_EJECT="Module ejected."
_NEXT ="Playing next subsong."
_QUIT ="Player terminated."

options results
parse arg file

if show('P','DELITRACKER') then do
    address 'DELITRACKER'
    if file="QUIT"  then call CustomQuit
    if file="EJECT" then call CustomEject
    if index("PLAYSTOP",file)>0 then do
        playpause
        say _PAUSE
        exit
    end
    if file="NEXT" then do
        NextSubSong;say _NEXT;Exit
    end
    Playmod file
    if rc>0 then break
    exit
end

if show('P','rexx_EP') then do
    address 'rexx_EP'
    if file="QUIT" then  call CustomQuit
    if file="EJECT" then call CustomEject
    if index("PLAYSTOP",file)>0 then do
        STATUS "G" "PLY"
        if result="yes" then STOP
        if result="no" then PLAY
        say _PAUSE
        exit
    end
    if file="NEXT" then do
        NEXTSONG;say _NEXT;Exit
    end
    LOADMODULE '"'file'"'
    PLAY
    exit
end

if show('P','HIPPOPLAYER') then do
    address 'HIPPOPLAYER'
    if file="QUIT" then  call CustomQuit
    if file="EJECT" then call CustomEject
    if index("PLAYSTOP",file)>0 then do
        Get PLAY
        if result=1 then STOP
        if result=0 then CONT
        say _PAUSE
        exit
    end
    if file="NEXT" then do
        Get CSNG;song=result
        Get NSNG
        If song<result then Songplay song+1
        say _NEXT
        Exit
    end
    Play file
    exit
end

if show('P','AMODPLAY') then do
    address 'AMODPLAY'
    if file="QUIT" then call CustomQuit
    if file="STOP" then call CustomStop
    if file="PLAY" then do
        cont
        say _PAUSE
    end
    if file="EJECT" then do
        unload;say _EJECT;exit
    end
    load file
    if rc>0 then break
    play
    exit
end

/** Multi_Player by Thomas Landspurg **/
if show('P','Multi_Player') then do
    address 'Multi_Player'
    if file="STOP" then call CustomStop
    if file="QUIT" then call CustomQuit
    if file="PLAY" then do
        start
        say _PAUSE
        exit
    end
    "Play "file
    if rc>0 then break
    exit
end

/** Multiplayer, ©1992 Bryan Ford **/
if show('P','RXTRACKER') then do
    address 'RXTRACKER'
    if file="QUIT" then call CustomQuit
    if file="STOP" then call CustomStop
    if file="EJECT" then do
        UNLOAD
        say _EJECT
        exit
    end
    if file="PLAY" then do
        CONTINUE
        say _PAUSE
        exit
    end
    play '"'file'"'
    if rc>0 then break
    exit
end
if show('P','PowerPlayer.REXX') then do
    address 'PowerPlayer.REXX'
    if file="QUIT" then do;PlQuit;exit;end
    if file="EJECT" then do;PlEject;exit;end
    if index("PLAYSTOP",file)>0 then do
        PlPause
        exit
    end
    PlLoad file
    exit
end

if show('P','DOPUS.1') then do
    address 'DOPUS.1'
    dopus version
    if (result='RESULT'|translate(result,'.',' ')<5) then break
    dopus getfiletype '"'file'"' ID
    if result='MOD' then do
        command play '"'file'"'
        if rc=0 then exit
    end
end

if show('P','PLAYSID') then do
    address 'PLAYSID'
    if index("PLAYSTOP",file)>0 then do
        SID_PAUSE()
        say _PAUSE
        exit
    end
    if file="QUIT" then do
        SID_QUIT()
        say _QUIT
        exit
    end
    SID_LOAD(file)
    SID_PLAY()
    exit
end
exit(5)

CustomStop:
    stop
    say _PAUSE
    exit
    return
CustomQuit:
    quit
    say _QUIT
    exit
    return
CustomEject:
    eject
    say _EJECT
    exit
    return